\start83\
\comment=Programm Dateidatum 08/26/01, 15:17
\name=RACER
\file=C:\PROGRA~1\TI-GRA~1\RACER.TXT
ClrHome
For(\theta\,1,16
Output(1,\theta\,"*
Output(8,\theta\,"*
End
Output(4,5,"Racer \^2\\cross\
Output(5,5,"By\1\HvdB
Output(5,7," 
Output(7,3,"Press Enter
Lbl I
For(C,1,16
Output(1,C," 
If C>1
Output(1,C-1,"*
Output(8,17-C," 
If 17-C<16
Output(8,18-C,"*
getKey
If Ans=105
Goto M
End
Output(1,16,"*
Output(8,1,"*
Goto I
Lbl M
Menu("    Racer 2+    ","START GAME",S,"HIGHSCORE",H,"QUIT",Q
Lbl Q
ClrHome
Output(1,1,"
Stop
Lbl H
Menu("HIGHSCORE","SHOW SCORE",8,"RESET SCORE",9,"CANCEL",M
Lbl 8
ClrHome
1\->\dim(\L\RACR
Output(4,3,"THE CURRENT
Output(5,1,"HIGHSCORE IS
Output(5,14,\L\RACR(1
Pause 
Goto M
Lbl 9
1\->\dim(\L\RACR
DelVar \L\RACR
ClrHome
Output(4,4,"HIGHSCORE
Output(5,4,"RESETTED.
Pause 
Goto M
Lbl S
ClrHome
8\->\P
0\->\S
0\->\T
For(\theta\,1,8
Disp "
End
Menu("DIFFICULTY:","EASY",1,"MEDIUM",2,"HARD",3
Lbl 1
8\->\O
4\->\W
Goto G
Lbl 2
7\->\O
5\->\W
Goto G
Lbl 3
6\->\O
6\->\W
Lbl G
0\->\G
While G=0
S+1\->\S
If W>1 and W+O<16
randInt(\(-)\1,1\->\R
If W=1
randInt(0,1\->\R
If W+O=16
randInt(\(-)\1,0\->\R
W+R\->\W
Output(8,W,"O
Output(8,W+O,"O
Output(7,P," 
getKey
If Ans=105
1\->\G
P-(Ans=24)+(Ans=26)\->\P
Output(8,P,"8
If P\<=\W or P\>=\W+O:2\->\G
Disp "
End
If G=1
Menu("GAME PAUSED","RESUME",G,"QUIT",Q
Lbl X
ClrHome
int(S/(O-3\->\S
Output(3,3,"YOU CRASHED     
Output(4,4,"POINTS:         
Output(4,12,S
1\->\dim(\L\RACR
If S>\L\RACR(1
Then
Output(5,2,"THIS IS A NEW   
Output(6,5,"RECORD!         
S\->\\L\RACR(1
Else
Output(5,2,"THE RECORD IS   
Output(6,5,"STILL          
Output(6,11,\L\RACR(1
End
Pause 
Goto M
\stop83\

